Формула для нахождение склонения луны

[V4L1K]

Всем привет, меня интересует именно ФОРМУЛА склонения луны, посылать меня на таблицы и планетарии не надо.

Мне нужно хоть какая то формула, которая зависит от возраста луны, дня в году, лунного узла и еще чего то там,
 я перелопатил много статей, но так и не нашел формулы.

Нашел только такое(https://helpiks.org/6-79203.html), но параметр t я не знаю как вычислять, поэтому я в тупике.

Буду вам очень благодарен за помощь.

[Toth]

меня интересует именно ФОРМУЛА склонения луны,

Вы про склонение в экваториальных координатах, про δ , Dec ?
Непонятно, зачем вам только склонение, без прямого восхождения.
Ну, ладно, вот код на Паскале, из книги О. Монтенбрук, Т. Пфлегер "Астрономия на персональном компьютере"
JD - это момент времени, на который вычисляются координаты. DEC - это и есть склонение.

(кликните для показа/скрытия)

(* MINI_MOON: low precision lunar coordinates (approx. 5'/1') *)
(* T : time in Julian centuries since J2000 *)
(* ( T=(JD-2451545)/36525 ) *)
(* RA : right ascension (in h; equinox of date) *)
(* DEC: declination (in deg; equinox of date) *)
procedure Mini_Moon (T: Double; VAR RA,DEC,r: Double);
CONST
 P2 =2*PI;
 ARC= 3600/GRAD_RAD; // 206264.8062;
 COSEPS=0.917482062;
 SINEPS=0.397777156; (* cos/sin(obliquity ecliptic) *)
VAR
 L0,L,LS,F,D,H,S,N,DL,CB : REAL;
 L_MOON,B_MOON,V,W,X,Y,Z,RHO: REAL;

 FUNCTION FRAC(X:REAL):REAL;
 (* with some compilers it may be necessary to replace *)
 (* TRUNC by LONG_TRUNC oder INT if T<-24! *)
 BEGIN X:=X-TRUNC(X); IF (X<0) THEN X:=X+1; FRAC:=X END;
 BEGIN
 (* mean elements of lunar orbit *)
 L0:= FRAC(0.606433+1336.855225*T);   (* mean longitude Moon (in rev) *)
 L :=P2*FRAC(0.374897+1325.552410*T); (* mean anomaly of the Moon *)
 LS:=P2*FRAC(0.993133+ 99.997361*T);  (* mean anomaly of the Sun *)
 D :=P2*FRAC(0.827361+1236.853086*T); (* diff. longitude Moon-Sun *)
 F :=P2*FRAC(0.259086+1342.227825*T); (* mean argument of latitude *)
 DL := +22640*SIN(L) - 4586*SIN(L-2*D) + 2370*SIN(2*D) + 769*SIN(2*L)
 -668*SIN(LS)- 412*SIN(2*F) - 212*SIN(2*L-2*D) - 206*SIN(L+LS-2*D)
 +192*SIN(L+2*D) - 165*SIN(LS-2*D) - 125*SIN(D) - 110*SIN(L+LS)
 +148*SIN(L-LS) - 55*SIN(2*F-2*D);
 S := F + (DL+412*SIN(2*F)+541*SIN(LS)) / ARC;
 H := F-2*D;
 N := -526*SIN(H) + 44*SIN(L+H) - 31*SIN(-L+H) - 23*SIN(LS+H)
 + 11*SIN(-LS+H) -25*SIN(-2*L+F) + 21*SIN(-L+F);
 L_MOON := P2 * FRAC ( L0 + DL/1296E3 ); (* in rad *)
 B_MOON := ( 18520.0*SIN(S) + N ) / ARC; (* in rad *)
 (* equatorial coordinates *)
 CB:=COS(B_MOON);
 X:=CB*COS(L_MOON);
 V:=CB*SIN(L_MOON);
 W:=SIN(B_MOON);
 Y:=COSEPS*V-SINEPS*W;
 Z:=SINEPS*V+COSEPS*W;
 RHO:=SQRT(1.0-Z*Z);
 r:=Sqrt(X*X+Y*Y+Z*Z); //  <--- добавлено
 DEC := (360.0/P2)*ARCTAN(Z/RHO);     // -> в градусы
 RA := ( 48.0/P2)*ARCTAN(Y/(X+RHO));  // -> в часы
 IF RA<0 THEN RA:=RA+24.0;
 END;

[V4L1K]

меня интересует именно ФОРМУЛА склонения луны,

Вы про склонение в экваториальных координатах, про δ , Dec ?
Непонятно, зачем вам только склонение, без прямого восхождения.
Ну, ладно, вот код на Паскале, из книги О. Монтенбрук, Т. Пфлегер "Астрономия на персональном компьютере"
JD - это момент времени, на который вычисляются координаты. DEC - это и есть склонение.

(кликните для показа/скрытия)

(* MINI_MOON: low precision lunar coordinates (approx. 5'/1') *)
(* T : time in Julian centuries since J2000 *)
(* ( T=(JD-2451545)/36525 ) *)
(* RA : right ascension (in h; equinox of date) *)
(* DEC: declination (in deg; equinox of date) *)
procedure Mini_Moon (T: Double; VAR RA,DEC,r: Double);
CONST
 P2 =2*PI;
 ARC= 3600/GRAD_RAD; // 206264.8062;
 COSEPS=0.917482062;
 SINEPS=0.397777156; (* cos/sin(obliquity ecliptic) *)
VAR
 L0,L,LS,F,D,H,S,N,DL,CB : REAL;
 L_MOON,B_MOON,V,W,X,Y,Z,RHO: REAL;

 FUNCTION FRAC(X:REAL):REAL;
 (* with some compilers it may be necessary to replace *)
 (* TRUNC by LONG_TRUNC oder INT if T<-24! *)
 BEGIN X:=X-TRUNC(X); IF (X<0) THEN X:=X+1; FRAC:=X END;
 BEGIN
 (* mean elements of lunar orbit *)
 L0:= FRAC(0.606433+1336.855225*T);   (* mean longitude Moon (in rev) *)
 L :=P2*FRAC(0.374897+1325.552410*T); (* mean anomaly of the Moon *)
 LS:=P2*FRAC(0.993133+ 99.997361*T);  (* mean anomaly of the Sun *)
 D :=P2*FRAC(0.827361+1236.853086*T); (* diff. longitude Moon-Sun *)
 F :=P2*FRAC(0.259086+1342.227825*T); (* mean argument of latitude *)
 DL := +22640*SIN(L) - 4586*SIN(L-2*D) + 2370*SIN(2*D) + 769*SIN(2*L)
 -668*SIN(LS)- 412*SIN(2*F) - 212*SIN(2*L-2*D) - 206*SIN(L+LS-2*D)
 +192*SIN(L+2*D) - 165*SIN(LS-2*D) - 125*SIN(D) - 110*SIN(L+LS)
 +148*SIN(L-LS) - 55*SIN(2*F-2*D);
 S := F + (DL+412*SIN(2*F)+541*SIN(LS)) / ARC;
 H := F-2*D;
 N := -526*SIN(H) + 44*SIN(L+H) - 31*SIN(-L+H) - 23*SIN(LS+H)
 + 11*SIN(-LS+H) -25*SIN(-2*L+F) + 21*SIN(-L+F);
 L_MOON := P2 * FRAC ( L0 + DL/1296E3 ); (* in rad *)
 B_MOON := ( 18520.0*SIN(S) + N ) / ARC; (* in rad *)
 (* equatorial coordinates *)
 CB:=COS(B_MOON);
 X:=CB*COS(L_MOON);
 V:=CB*SIN(L_MOON);
 W:=SIN(B_MOON);
 Y:=COSEPS*V-SINEPS*W;
 Z:=SINEPS*V+COSEPS*W;
 RHO:=SQRT(1.0-Z*Z);
 r:=Sqrt(X*X+Y*Y+Z*Z); //  <--- добавлено
 DEC := (360.0/P2)*ARCTAN(Z/RHO);     // -> в градусы
 RA := ( 48.0/P2)*ARCTAN(Y/(X+RHO));  // -> в часы
 IF RA<0 THEN RA:=RA+24.0;
 END;

Мне надо только склонение потому что только его я вычислить не могу,а прямое восхождение я умею вычислять.
Я вам благодарен за ответ,но мне надо более компакное решение.Например что то вроде такого как для солнца:
Dec = (24/PI)*acos(360*((d-81)/365))

[Toth]

но мне надо более компакное решение

Чем точнее, тем менее компактно.
Вам какая точность нужна ( в градусах ), и на какой период времени ?
И какие координаты нужны -
- средние на эпоху J2000.0
- средние на дату
- истинные на дату

[Toth]

но параметр t я не знаю как вычислять,

Судя по формуле, t0 - это когда совпало начало драконического и сидерического месяцев.
А (t-t0) - дней с этого момента.

Но, вообще, статья какая-то мутная. Явно не астроном писал.

[V4L1K]

но мне надо более компакное решение

Чем точнее, тем менее компактно.
Вам какая точность нужна ( в градусах ), и на какой период времени ?
И какие координаты нужны -
- средние на эпоху J2000.0
- средние на дату
- истинные на дату

Что до точности то мне надо хотя бы пол градуса(на крайняк градус) точность
Думаю мне надо хотя бы средние на день,а что вы имеете ввиду под истинные на дату?

[Toth]

.. а что вы имеете ввиду под истинные на дату?

То есть вообще в координатах не разбираетесь?
Вот, посмотрите https://ru.wikipedia.org/wiki/Эпоха_(астрономия), и https://ru.wikipedia.org/wiki/Предварение_равноденствий
Но, если точность полградуса , то все равно какие, между ними разница сейчас порядка 0.3 градуса .
Кстати, полградуса - это видимый диаметр Луны.

Но все равно, даже с такой точностью более-менее компактная формула - это на неск. лет, на столетия-тыщщелетия нереально, там довольно громоздкие. Мне так кажется.

Кстати, -

,а прямое восхождение я умею вычислять.

а что у вас за формула? На какой период действует, и какая точность ?

[V4L1K]

.. а что вы имеете ввиду под истинные на дату?

То есть вообще в координатах не разбираетесь?
Вот, посмотрите https://ru.wikipedia.org/wiki/Эпоха_(астрономия), и https://ru.wikipedia.org/wiki/Предварение_равноденствий
Но, если точность полградуса , то все равно какие, между ними разница сейчас порядка 0.3 градуса .
Кстати, полградуса - это видимый диаметр Луны.

Но все равно, даже с такой точностью более-менее компактная формула - это на неск. лет, на столетия-тыщщелетия нереально, там довольно громоздкие. Мне так кажется.

Кстати, -

,а прямое восхождение я умею вычислять.

а что у вас за формула? На какой период действует, и какая точность ?

Она базируеться на прямом восхождении солнца и возрасте луны.
Сама формула:
 а луны = а солнца + (возраст луны * 12.2°)

[Toth]

Она базируеться на прямом восхождении солнца и возрасте луны.

Слишком мудрено. Я думал проще, когда всего 1 аргумент - время ( например, количество дней от даты 01.01.2000 ).
Хотя для RA Солнца и возраста Луны - должна быть формула с этим одним аргументом.
Ну, ладно, наверное для вычисления RA Солнца и возраста Луны - у вас компактная формула.

Вы её проверяли на точность? Можно например тут - http://vo.imcce.fr/webservices/miriade/?forms
Проверьте например на 1 и 2 июля 2020 г. См. рис -

PS И зачем вы цитируете весь пост, это захламляет.

[V4L1K]

Слишком мудрено. Я думал проще, когда всего 1 аргумент - время ( например, количество дней от даты 01.01.2000 ).

Как для меня, когда только 1 аргумент это слишком мудрено, для компьютера возможно в самый раз считать, но для меня - ну такое.А вот обычные аналитические формулы считать самый раз)

Ну, ладно, наверное для вычисления RA Солнца и возраста Луны - у вас компактная формула.

Да, возраст луны я так считаю:
возраст = месяц* + день + лунное число(в 2020 - 4).
месяц* = для формул надо брать текущий месяц(7-1 =6 например),а что бы реальный узнать возраст надо отнять 1 от результата.

А прямое восх. для солнца = (d-80*)/15
80* - это для обычного года, для высокосного будет 81. Это дней до зимнего солцестояния если не ошибаюсь.

Мои значения а солнца   Дата          прям.восх.     ошибка 1.07.2020   6h43m59.99s       ~0.5m 2.07.2020   6h48m00s       ~0.5m Мои значения а луны   Дата                   возраст                    прям.восх.          ошибка 1.07.2020     10д(11 в формуле)        15h 31m 59.99s       ~15.86m 2.07.2020     11д(12 в формуле)       16h 24m 00s       ~11.44m PS И зачем вы цитируете весь пост, это захламляет. Я тогда просто с телефона сидел, а там мне неочень удобно было выделять и убирать теги

[Toth]

А ну, если вы еще и Солнце считаете, то ладно. Кстати, движение Солнца проще рассчитывается, чем Луны, у Луны в " теории движения " больше членов при заданной точности.

Вот, нашел самое компактное, у D.Vallado . Выбрал для dec. 1 аргумент - дата/ время JD
T= ( JD - 2451545.0 ) / 36525.0   
Эклиптическая долгота Луны
 L= 3.8104028 + 8399.7091*T
          +0.1097812*Sin(2.3544491+8328.6911*T)
           -0.022165*Sin(4.5238934-7214.063*T)
          +0.0115191*Sin(4.1137410+15542.754*T)
          +0.0036651*Sin(4.7106436+16657.382*T)
           -0.003316*Sin(6.2395520+628.30195*T)
           -0.001919*Sin(3.2567843+16866.932*T)
Эклиптическая широта Луны
 B=   0.08953539*Sin( 1.62839219+8433.46637*T )
           + 0.00488692*Sin( 3.98284135+16762.15732*T)
           - 0.00488692*Sin( 5.555383+  104.7752565*T)
          - 0.002967059*Sin( 3.79783645-7109.288039*T)
Перевод в экваториальные
 Dec=ArcSin(0.397735506*Cos(B)*Sin(L) + 0.917500118*Sin(B))

Все в радианах, ибо и в Паскаль и в Си и в Excel - синусы, косинусы питаются радианами.
Проверял, отклонение с mean J2000 на период 1990..2030 - не более 0.3 град.

Вот первоисточник - там всякие переводы рад-> град->рад.. Но там видно, каков примерно вклад каждого слагаемого в градусах.

(кликните для показа/скрытия)

|                           PROCEDURE MOON
|
|  This PROCEDURE calculates the Geocentric Equatorial (IJK) position vector
|    for the MOON given the Julian Date.
|
|  Author        : David Vallado                  719-573-2600    1 Mar 2001
|
|  Inputs          Description                    Range / Units
|    JD          - Julian Date                    days from 4713 BC
|
|  Outputs       :
|    RMoon       - IJK Position vector of MOON    ER
|    RtAsc       - Right Ascension                rad
|    Decl        - Declination                    rad
|
|  Locals        :
|    EclpLong    - Ecliptic Longitude
|    EclpLat     - Eclpitic Latitude
|    HzParal     - Horizontal Parallax
|    l           - Geocentric Direction Cosines
|    m           -             "     "
|    n           -             "     "
|    TTDB        - Julian Centuries of TDB from
|                  Jan 1, 2000 12h
|    Hr          - Hours                          0 .. 24
|    MIN         - Minutes                        0 .. 59
|    SEC         - Seconds                        0.0 .. 59.99
|    deg         - Degrees
|
|  Coupling      :
|    MODFUNC       MOD FUNCTION for REAL variables
|    ASIN        Arc Sine FUNCTION
|    ATAN2         Arc Tangent formula which resolves quadrants
|
|  References    :
|    Vallado       2007, 290, Alg 31, Ex 5-3
|
 ----------------------------------------------------------------------------- }
{}
PROCEDURE MOON               ( JD                                    : EXTENDED;
                               VAR RMoon                             : Vector;
                               VAR RtAsc,Decl                        : EXTENDED );
   CONST
     TwoPi      : EXTENDED =     2.0 * pi;  { 6.28318530717959; }
     Deg2Rad    : EXTENDED =     pi /180.0;  { 0.01745329251994; }
   VAR
     Hr, MIN, Deg : INTEGER;
     SEC, TTDB, l, m, n, Temp, Obliquity,
     EclpLong, EclpLat, HzParal : EXTENDED;
   BEGIN
     { --------------------  Initialize values   -------------------- }
     TTDB := ( JD - 2451545.0 ) / 36525.0;

     EclpLong:= 218.32 + 481267.883*TTDB
                + 6.29*SIN( (134.9+477198.85*TTDB)*Deg2Rad )
                - 1.27*SIN( (259.2-413335.38*TTDB)*Deg2Rad )
                + 0.66*SIN( (235.7+890534.23*TTDB)*Deg2Rad )
                + 0.21*SIN( (269.9+954397.70*TTDB)*Deg2Rad )
                - 0.19*SIN( (357.5+ 35999.05*TTDB)*Deg2Rad )
                - 0.11*SIN( (186.6+966404.05*TTDB)*Deg2Rad );     { Deg }

     EclpLat :=   5.13*SIN( ( 93.3+483202.03*TTDB)*Deg2Rad )
                + 0.28*SIN( (228.2+960400.87*TTDB)*Deg2Rad )
                - 0.28*SIN( (318.3+  6003.18*TTDB)*Deg2Rad )
                - 0.17*SIN( (217.6-407332.20*TTDB)*Deg2Rad );     { Deg }

     HzParal :=   0.9508 + 0.0518*COS( (134.9+477198.85*TTDB)*Deg2Rad )
                + 0.0095*COS( (259.2-413335.38*TTDB)*Deg2Rad )
                + 0.0078*COS( (235.7+890534.23*TTDB)*Deg2Rad )
                + 0.0028*COS( (269.9+954397.70*TTDB)*Deg2Rad );   { Deg }

     EclpLong := MODFUNC( EclpLong*Deg2Rad, TwoPi );
     EclpLat  := MODFUNC( EclpLat*Deg2Rad, TwoPi );
     HzParal  := MODFUNC( HzParal*Deg2Rad, TwoPi );  // перевод град -> рад, и приведение к диапазону 0..2пи

     Obliquity:= 23.439291 - 0.0130042*TTDB; {deg}  // это ε,  оно очень мало меняется, я его принял постоянным
     Obliquity:= Obliquity *Deg2Rad;

     { ------------- Find the geocentric direction cosines ---------- }
     l:= COS( EclpLat ) * COS( EclpLong );
     m:= COS(Obliquity)*COS(EclpLat)*SIN(EclpLong)
         - SIN(Obliquity)*SIN(EclpLat);
     n:= SIN(Obliquity)*COS(EclpLat)*SIN(EclpLong)
         + COS(Obliquity)*SIN(EclpLat);

     { -------------- Calculate MOON position vector ---------------- }
     RMoon[4]:= 1.0/SIN( HzParal );
     RMoon[1]:= RMoon[4]*l;
     RMoon[2]:= RMoon[4]*m;
     RMoon[3]:= RMoon[4]*n;

     { --------------- Find Rt Ascension and Declination ------------ }
     RtAsc:= ATAN2( m,l );
     Decl := ASIN( n );

    // дальше - вывод в командной строке, я его убрал
   END;  { PROCEDURE MOON }

[V4L1K]

Спасибо большое вам